extends Node
class_name MapController

const PLAYER_SPAWNER: String = "res://scenes/maps/base/player_spawner/player_spawner.tscn"
const BULLET_SPAWNER: String = "res://scenes/maps/base/bullet_spawner/bullet_spawner.tscn"
const ENTRY_SCREEN: String = "res://scenes/maps/base/entry_screen/entry_screen.tscn"

var player_spawner: PlayerSpawnerController
var bullet_spawner: BulletSpawnerController
var entry_screen: Control

var client_node: Node3D

@onready var spawn_controller: SpawnController = $SpawnLocations

# Called when the node enters the scene tree for the first time.
func _ready() -> void:
	# add player spawner
	var err: Error = OK
	err = _add_player_spawner()
	if err != OK:
		push_error("Couldn't load player spawner")
	
	err = _add_bullet_spawner()
	if err != OK:
		push_error("Couldn't load bullet spawner")
	
	# add objects spawner
	if not OS.has_feature("dedicated_server"):
		err = _add_entry_screen()
		if err != OK:
			logger.error("Couldn't load the entry screen, err " + str(err))
	

@rpc("any_peer", "call_local", "unreliable")
func _spawn_player_controller_node(x: float, y: float, z: float):
	var path := "res://scenes/player/player_node.tscn"
	var scene: PackedScene = ResourceLoader.load(path)
	var player_node: PlayerNode = scene.instantiate()
	player_node.name = "PlayerController"
	var controlled_node: ServerNode = player_spawner.get_player_node(multiplayer.get_unique_id())
	player_node.controlled_node = controlled_node
	client_node.add_child(player_node)
	player_node.shared_node.global_position  = Vector3(x,y,z)
	controlled_node.bind_player_node()
	
func spawn_player_model(owner_node: CharacterBody3D, owner_id: int):
	if multiplayer.get_unique_id() != owner_id:
		player_spawner.spawn_player_model(owner_node)
	
func _remove_player(id: int):
	player_spawner.remove_player(id)
	

func _add_player_spawner() -> Error :
	if not ResourceLoader.exists(PLAYER_SPAWNER):
		return ERR_DOES_NOT_EXIST
	var scene: PackedScene = ResourceLoader.load(PLAYER_SPAWNER)
	if not scene.can_instantiate():
		return ERR_CANT_OPEN
	
	var node: PlayerSpawnerController = scene.instantiate()
	add_child(node)
	player_spawner = node
	player_spawner.spawn_controller = spawn_controller
	return OK
	
func _add_bullet_spawner() -> Error :
	if not ResourceLoader.exists(BULLET_SPAWNER):
		return ERR_DOES_NOT_EXIST
	var scene: PackedScene = ResourceLoader.load(BULLET_SPAWNER)
	if not scene.can_instantiate():
		return ERR_CANT_OPEN
	var node: BulletSpawnerController = scene.instantiate()
	add_child(node)
	bullet_spawner = node
	return OK

func _add_entry_screen() -> Error :
	if not ResourceLoader.exists(ENTRY_SCREEN):
		return ERR_DOES_NOT_EXIST
	var scene: PackedScene = ResourceLoader.load(ENTRY_SCREEN)
	if not scene.can_instantiate():
		return ERR_CANT_OPEN
	var node: Control = scene.instantiate()
	add_child(node)
	entry_screen = node
	return OK
	
# -- TODO: Better bullet naming handler
var bullet_amount: int = -2147483647
func spawn_bullet(starting_point: Node3D, speed: int, damage: int):
	bullet_spawner.spawn_bullet(starting_point, speed, damage)